Přerušení

; inicializace

loop:
    ; if(aktivni_flag_preruseni) {
    ;   deaktivuj flag;
    ;   zareaguj;
    ; }
jmp loop

; konec hlavniho programu

interrupt:
    ; proved uklid
    ; aktivuj flag
    ; proved obnovu
reti                 ; 1

1. reti je návrat z kódu přerušení. Chová se podobně jako ret, ale ještě povolí globální přerušení (jako by tam byly dvě instrukce sei a ret).

.dseg                ; prepnuti do pameti dat 1
.org 0x100           ; od adresy 0x100 (adresy 0 - 0x100 nepouzivejte)

flag: .byte 1        ; rezervovani mista pro 1 bajt

.cseg                ; prepnuti do pameti programu
; podprogramy pro praci s displejem
.org 0x1000
.include "printlib.inc"

; Zacatek programu - po resetu
.org 0
    jmp	start
.org 0x16            ; 2
    jmp interrupt

.org 0x100

start:
    ; Inicializace displeje
    call init_disp
    ; Inicializace preruseni od casovace
    call init_int

    ldi r16, 0       ; 3
    sts flag, r16

    ldi r17, 0
    ldi r16, '0'
    call show_char

main_loop:
    lds r20, flag
    cpi r20, 0       ; nacteni a otestovani hodnoty flag-u
    breq main_loop   ; pokud neni flag -> navrat na zacatek
                     ; je flag
    ldi r20, 0       ; vycisteni flag-u
    sts flag, r20

    ; akce provedena 1x za sekundu 4
    inc r16
    call show_char

    jmp main_loop

end: jmp end

init_int:            ; 5
    push r16
    cli ; globalni zakazani preruseni

    ; vycisteni aktualni hodnoty citace TCNT1 (aby prvni sekunda nezacala nekde "od pulky")
    clr r16
    ; Neprehazujte poradi nahravani TCNT1H a TCNT1L - hodnota by se nemusela spravne ulozit!
    sts TCNT1H, r16
    sts TCNT1L, r16

    ; povoleni preruseni ve chvili, kdy citac TCNT1 dosahne hodnoty OCR1A
    ldi r16, (1<<OCIE1A)
    sts TIMSK1, r16

    ; nastaveni cisteni citace TCNT1 ve chvili, kdy dosahne hodnoty OCR1A (1<<WGM12)
    ; nastaveni preddelicky na 1024 (0b101<<CS10 - bity CS12, CS11 a CS10 jsou za sebou)
    ldi r16, (1<<WGM12) | (0b101<<CS10)
    sts TCCR1B, r16

    ; nastaveni OCR1A, tj. vysledne frekvence preruseni
    ; frekvence preruseni = frekvence cipu 328P / preddelicka / (OCR1A+1)
    ; frekvence cipu 328P je 16 MHz, tj. 16000000
    ; preddelicka je nastavena na 1024
    ; frekvenci preruseni chceme na 1 Hz
    ; OCR1A = (frekvence cipu 328P / preddelicka / frekvence preruseni) - 1
    ; OCR1A = (16000000 / 1024 / 1) - 1
    ; OCR1A = 15624
    ; 16bitovou hodnotu je treba nastavit do dvou registru OCR1AH:OCR1AL
    ; 15624 = 61 * 256 + 8
    ; Neprehazujte poradi nahravani OCR1AH a OCR1AL - hodnota by se nemusela spravne ulozit!
    ldi r16, 61
    sts OCR1AH, r16
    ldi r16, 8
    sts OCR1AL, r16

    ; zakazani preruseni od tlacitek
    clr r16
    out EIMSK, r16

    sei ; globalni povoleni preruseni
    pop r16
    ret

interrupt:           ; 6
    ; uklid registru a SREG
    push r16
    in r16, SREG
    push r16

    ; nastav flag
    ldi r16, 1
    sts flag, r16

    ; obnoveni SREG a registru
    pop r16
    out SREG, r16
    pop r16
    reti             ; 7

1. Více detailů o práci s datovou pamětí naleznete zde.
2. Na adrese 0x16 je vektor přerušení pro časovač 1 v námi používaném módu. Na okolních adresách jsou další vektory přerušení, proto je na dané adrese pouze jmp interrupt. Přerušení de facto zakáže ostatní přerušení a zavolá podprogram na 0x16 (jako by se zavolaly dvě instrukce cli a call 0x16), proto na dané adrese 0x16 nesmí být další call.
3. Inicializace paměťového místa (ani paměť ani registry nejsou na vývojovém kitu inicializovány automaticky).
4. Zde jen jednoduchý inkrement a vytištění hodnoty na displej.
5. Více detailů o inicializaci naleznete na začátku této stránky.
6. Přerušení je co nejkratší, obsahuje jen úklid, nezbytnosti k nastavení flagu a obnovení.
7. reti je návrat z kódu přerušení. Chová se podobně jako ret, ale ještě povolí globální přerušení (jako by tam byly dvě instrukce sei a ret).