OpenSCAD

CSG modelování

CSG modelování (Constructive Solid Geometry) je vektorové modelování grafických prvků, v našem případě 3D modelů. Základní primitiva (koule, kužel/válec, kvádr…) se skládají do CSG stromu pomocí hran transformací (posun, škálování, rotace…) a uzlů booleovských operací (rozdíl, průnik, sloučení).

Na obrázku vidíte ilustraci CSG stromu. Zde jsou pro zjednodušení primitivy již otočené.

OpenSCAD umožňuje takové stromy zapsat pomocí kódu a vyrenderovat z nich výsledný 3D model ve formě triangulární meshe (o té se budeme učit později).

Uživatelské rozhraní

Okno programu se skládá ze tří částí:

Po napsání kódu do editoru je třeba model „zkompilovat“. Existuje rychlý (ne vždy přesný) náhled pomocí OpenGL (Design → Zobrazit, F5) a plnohodnotný render do 3D modelu pro export (počítá se bohužel na procesoru, Design → Vyrenderovat, F6). V nabídce Design lze zapnout i Automaticky načítat a zobrazovat, po uložení se pak provede náhled automaticky.

V nabídce Zobrazit najdete spousto možností pro zobrazení náhledu, doporučujeme zapnout osy a pravítko.

Pro pohyb modelem později použijete myš (vyzkoušejte různá tlačítka).

Abyste něco viděli, potřebujete ale zdrojový kód. Můžete si vybrat z pestré nabídky Soubor → Příklady.

Syntax

Syntaxe je hned na první pohled velmi podobná C/C++/Javě – obsahuje středníky, chlupaté závorky, komentáře se píší stejně. Kromě jiného můžete psát čísla (buď celá, nebo s plovoucí desetinnou čárkou (zápis pomocí tečky nebo vědecky)) – 1, 0, -5, 5.3, 9.99998, 185e-5; vektory/souřadnice v hranatých závorkách – [1, 2, 3]; řetězce ve "dvojitých uvozovkách", boolean true/false.

Můžete používat proměnné (které se nedeklarují, ale chovají se nestandardně, k tomu se dostaneme dále), matematické výrazy a funkce, konstantu PI…

Primitiva

cube(150, center=true); 1
sphere(100); 2

Transformace

Když už umíte vytvářet primitivní geometrická tělesa, je dobré naučit se s nimi provádět jednotlivé transformace.

Transformace se aplikují zápisem před objekt, který chcete transformovat: transformace() objekt();. Dají se také řetězit, jsou aplikované postupně od „nejbližší“ po nejvzdálenější. Dají se aplikovat i na více objektů současně, zabalením objektů do chlupatých závorek a předsazením před ně.

transformace() {
  objekt1();
  objekt2();
}

color("green") rotate([0,0,60]) translate([30,0,0]) cube(5); 1
color("red") translate([30,0,0]) rotate([0,0,60]) cube(5); 2

Booleovské operace

Základem CSG modelování jsou tři boolovské operace:

union() {
  cube(150, center=true);
  sphere(100);
}

difference() {
  cube(150, center=true);
  sphere(100);
}

intersection() {
  cube(150, center=true);
  sphere(100);
}

Všechny tyto operace nemají žádné argumenty, ale zpracují libovolný počet objektů. Takovým objektům se říká children dané operace. Česky to znamená děti, ale my tento pojem raději překládat nebudeme.

Použití proměnných

Není nutné všude používat hodnoty přímo, v OpenSCADu se dají používat i proměnné.

awesome = 42;
cylinder(h=awesome, r=awesome/2);

Mějte ale na paměti fakt, že všechno se děje zároveň. Proměnou proto nelze předefinovat, respektive lze, ale chová se to jinak, než jste zvyklí.

awesome = 42;
echo(awesome); 1
awesome = 4242; 2
echo(awesome);

Výsledkem je dvakrát vypsané ECHO: 4242 🤯 Důvodem je to, že nezáleží, kdy proměnnou nastavíte, její hodnota platí v celém scopu. Pokud proměnnou nastavíte v jednom scopu dvakrát, platí později uvedená hodnota, to berte ale jen jako implementační detail a nikdy to nedělejte.

Pomůže o proměnných uvažovat jako o konstantách pro daný scope. Zatím známe jen jeden (globální) scope, ale to se brzy změní.

Cykly

Syntaxe foru je kapku odlišná od C a vypadá asi takto:

for (var = [...]) { 1
    ... 2
}

Zastavme se na chvíli u zápisu vektorů, které jde zapsat několika způsoby:

Toho často využijeme v zápisu cyklu for.

for (i = [0:10:100]) echo(i); // => ECHO 10, 20, 30...

intersection_for(n = [1 : 6]) {
  rotate([0,0,n*60]) translate([5,0,0]) sphere(12);
}

Cykly lze samozřejmě do sebe vnořovat, existuje k tomu i zkratka.

for (xpos=[0:3]) {
  for (ypos=[2,4,6]) { 1
    ...
  }
}

for (xpos=[0:3], ypos=[2,4,6]) { 2
  ...
}

1. Vnořený cyklus
2. Zkratka (syntactic sugar) pro vnořený cyklus

Vzhledem k tomu, jak cyklus for v OpenSCADu funguje, zde vypichujeme několik informací, na které pozorný čtenář jistě již přišel sám:

Podmínky

OpenSCAD obsahuje dva druhy podmínek: if a ternární operátor.

if (...) { 1
  ... 2
} else if (...) { 3
  ... 4
} else { 5
  ... 6
}

num = 42;

if (num > 0) {
  sign = 1;
} else if (num < 0) {
  sign = -1;
} else {
  sign = 0;
}

echo(sign); // WARNING: Ignoring unknown variable 'sign'.

num = 42;

// var =   test ? TrueValue : FalseValue;

sign = num > 0 ? 1 : (num < 0 ? -1 : 0); 1
echo(sign); // ECHO: 1

Funkce

Podobně jako ternární operátor se zapisují funkce. Funkce nevytváří části CSG stromu, pouze počítají nějakou hodnotu ze svého vstupu. Jsou to jednovýrazové zkratky.

function name ( parameters ) = expression;

Funkcemi se v tomto kurzu moc nezabýváme, ale zvídaví studenti je mohou samozřejmě používat. Více o funkcích v manuálu.

Moduly

Ekvivalentem k funkci pro CSG strom je modul. Modul se více podobá funkcím, jak je známe z programovacích jazyků, s tím rozdílem, že nevrací žádnou hodnotu, ale uzel (či hranu) CSG stromu.

Laicky řečeno: modul něco „nakreslí“ tam, kde se použije.

Stejně jako funkce, přijímá modul parametry, které mohou nabývat výchozích hodnot. Navíc může přijímat (zpracovávat) children().

Moduly (a funkce) mohou existovat v samostatných souborech (knihovnách), ve vlastním souboru s modelem můžete použít use nebo include:

module rounded_cylinder(h=20, r=5, center=false) {
  baseh = h-2*r;
  translate([0, 0, center ? -baseh/2 : r]) {
    cylinder(h=baseh, r=r);
    sphere(r);
    translate([0, 0, baseh]) sphere(r);
  }
}

// pro zobrazení musíte modul zavolat
rounded_cylinder(center=true);

children()

Kromě modulů, které vytvářejí tvary jen na základě vstupních parametrů (argumentů), jdou vytvářet i moduly, které přijímají children().

Používá se to na modifikování nebo zakomponování libovolného objektu.

children()

reprezentuje všechny předané objekty

children(n)

reprezentuje n-tý předaný objekt

children([n1, …​, nx])

reprezentuje n-první až n-x-tý předaný objekt

$children

magická (s dolarem) konstanta s počtem předaných objektů

children([1 : 2 : $children])

každý druhý předaný objekt

module elongate() {
  scale([10 , 1, 1])
    children();
}

elongate() {
  sphere(30);
  cube(45, center=true);
  cylinder(r=10, h=50);
}

Debugging

Pro debugging modelů je dobbré naučit si několik modifikátorů:

difference() {
  sphere(45);
  #cube(65, center=true);
}

Pomocníčci

Speciálními operacemi v OpenSCADu jsou minkowski() a hull(). Pomocí nich můžete vyvářet složité tvary, které by se jinak vytvářely velice obtížně.

Minkowského suma

Minkowského suma je množinová operace, kdy všechny body z jedné množiny sečtete se všemi body z druhé množiny. Nejlépe to vystihuje následující obrázek:

Můžete si to představit tak, že jeden z objektů uchopíte za počátek souřadný a objíždíte s ním po povrchu druhého objektu, zanechávajíc za sebou stopu. Jedná se o operaci komutativní a asociativní, je tedy jedno, kterým objektem jezdíte po kterém. V praxi se tato operace používá většinou s koulí pro zaoblení, ale pozor, zaoblený objekt se zvětší.

minkowski() {
  cube(300);
  sphere(30);
}

Varování:

Vypočtení minkowského sumy může trvat velmi dlouho.

Konvexní obal

Konvexní obal (convex hull) objektů je takový nejmenší konvexní objekt, který pojme všechny objekty v něm. Opět se jedná o komutativní a asociativní množinovou operaci.

hull() {
  cube(100);
  sphere(30);
}

Varování:

Vypočtení konvexního obalu může trvat celkem dlouho.

Dvourozměrný subsystém

Zatím jsme vytvářeli jen trojrozměrné objekty. V OpenSCADu se dá ale využít dvourozměrný subsystém, ve kterém se pracuje jen na jedné rovině.

V 2D subsystému je možné vyvářet 2D primitiva: circle(), square() a polygon().

Pomocí linear_extrude() nebo rotate_extrude() jde z 2D objektu vytvořit 3D objekt. Naopak projection() slouží k projekci 3D objektů do 2D.

Když pracujete ve 2D subsystému, lze použít vše, co již znáte, jen API některých operací se náležitě změní (např. translate() bere vektor 2 hodnot, rotate() bere jen jeden úhel…).

hull() {
  rotate(45) square([25, 15]);
  translate([12, 7]) circle(7);
}

Operace hull() a minkowski() jsou ve 2D subsystému relativně rychlé. Pokud to jde, je tedy lepší provádět je v něm.

offset()

K zaoblení dvourozměrných tvarů lze použít offset(). Ten má několik způsobů použití:

linear_extrude()

Operace linear_extrude() vytáhne 2D tvar do prostoru a vytvoří tedy 3D tvar. Lze nastavit několik parametrů:

height

výška vytažení

center

false vytahuje jen nahoru, true na oba směry (každý o polovinu výšky)

twist

o kolik stupňů se 2D tvar při vytažení otočí

slices

počet kroků u twist

scale

kolikrát se 2D tvar při vytažení zvětší

convexity

hodnota ovlivňující náhled; kuchař radí: „nevíš-li, dej tam 10“

linear_extrude(height=20, twist=180, slices=100, center=true) {
  square(5);
  square(5, center=true);
}

rotate_extrude()

Další možností, jak převést 2D tvar na 3D tvar, je rotovat ho. K tomu slouží rotate_extrude(), které rotuje 2D tvar do prostoru.

Rotace probíhá kolem osy Y, ale objekt se „vzpřímí“ kolem osy Z (dodnes nevíme proč).

rotate_extrude()
  polygon(points=[[0,0],[20,10],[10,20],[10,30],[30,40],[0,50]]);

projection()

Projekce (projection()) promítne 3D objekt na rovinu XY. Parametr cut umožní použít jen průnik s rovinou XY. Výsledkem projekce je vždy 2D tvar; ten pak můžete využít opět k vytvoření 3D tvaru.

projection(cut=true)
  translate([0, 0, -15])
    rotate([45, 0, 0])
      cylinder(r1=0, r2=500, h=500);

import()

Pro použití již existujících 2D nebo 3D tvarů můžete použít import(), pomocí něhož lze do CSG stromu vložit STL a DXF soubory. Argumentem je cesta k souboru (relativní či absolutní).

Při importování 2D tvarů (DXF) si dejte především pozor na výslednou velikost, je vhodné použít resize().

rotate_extrude()
  resize([20, 0], auto=[false, true])
    import("bottle.dxf");

Importované soubory lze využít k jakýmkoliv dalším operacím. Cizí STL soubory se ne vždy povedou vyrenderovat, je třeba je nejprve opravit, k tomu se dostaneme ve cvičení o opravě meshe.

difference() {
  import("kangaroo.stl"); // http://www.thingiverse.com/thing:33273 CC BY-NC-SA
  translate([0, -10, 80])
    cube(30, center=true);
}

surface()

Alternativním způsobem využité externích souborů je surface(), který slouží k převodu obrázků do výškové mapy.

Rozlišení

Jistě jste si všimli, že kulaté věci jsou v OpenSCADu hranaté. Čím menší jsou, tím je to více poznat.

Pomocí speciálních proměnných $fn, $fa a $fs lze rozlišení měnit, viz manuál. V praxi se nejčastěji nastavuje proměnná $fn, která nastaví absolutní počet hran na kruh (minimálně 3). Tvary jsou vytvořené tak, že zadaná velikost je velikost opsané kružnice. Proměnou $fn lze využít například k vytvoření n-úhelníku.

Tyto speciální proměnné se mohou nastavit globálně, ve scopu nebo argumentem libovolné operaci, primitivu či modulu. Při vytváření modulů není třeba tyto proměnné uvádět v předpisu.

Simple – 2-Manifold

Pro správný export STL souboru je potřeba, aby byl model Simple – 2-Manifold. To mj. znamená, že stěny modelu se nemohou všelijak protínat. Skoro všechny možné problémy řeší výsledný implicitní union(). Nějaké problémy ale přece jen můžou vzniknout, například při nesprávném použití polyhedronu.

Jedním z problémů, který může nastat jednoduše, je společná hrana dvou objektů. Pokud si představíte dvě kostky (např. z obrázku níže), v reálném světě nemohou mít společnou hranu. Buďto jde „projít“ z jedné kostky do druhé, nebo „jde projít“ mezi nimi; jinými slovy buďto to jsou dvě kostky nebo jedna dvoukostka.

cube(20);
translate([20, 20, 0]) cube(20);

e=0.0001;
cube(20);
translate([20-e, 20-e, 0]) cube(20);

e=0.0001;
cube(20);
translate([20+e, 20+e, 0]) cube(20);

Knihovna MCAD

Pomocí modulů lze pro OpenSCAD vytvářet různé knihovny. Některé již existují, jednou z nich je knihovna MCAD, která bývá často distribuovaná společně s OpenSCADem.

Knihovna MCAD obsahuje spoustu elementárních i pokročilých věcí:

Pro použití knihovny MCAD je potřeba použít include, ne use.

include <MCAD/stepper.scad>
motor(Nema17);

Pokročilá práce s proměnnými

Příklady ze cvičení